onivim2.nix

# nix-build -E '((import <nixpkgs> {}).callPackage ./nix/onivim2.nix {})'
{ stdenv, lib, appimageTools, requireFile, autoPatchelfHook, makeWrapper, pango, cairo, gobject-introspection, glib, epoxy, libgpgerror, gdk-pixbuf, libxkbcommon, gtk3, ncurses5, acl, xorg, libGLU }:
stdenv.mkDerivation {
  name = "Oni2";
  version = "0.5.9-nightly";
  dontStrip = true;
  buildInputs = [
    autoPatchelfHook
    pango
    cairo
    gobject-introspection
    glib
    epoxy
    libgpgerror
    gdk-pixbuf
    libxkbcommon
    gtk3
    ncurses5
    acl
    libGLU
  ] ++ (with xorg; [
    libXinerama
    libXt
    libXi
    libXrandr
    libSM
    libICE
    libxkbfile
  ]);
  nativeBuildInputs = [ makeWrapper ];
  src = appimageTools.extractType2 {
    name = "onivim2";
    src = requireFile {
      name = "Onivim2-x86_64-master.AppImage";
      sha256 = "czEH/GKljwC6t1YUKTsCI0KSLlcPoyuEQn3wTE1fpUw=";
      url = "https://v2.onivim.io/early-access-portal";
    };
  };
  installPhase = ''
    mkdir -p $out/bin
    mv usr/bin $out/libexec
    mv usr/share $out
    mv EULA.md $out/libexec
    mv ThirdPartyLicenses.txt $out/libexec
    makeWrapper $out/libexec/Oni2 $out/bin/Oni2
    makeWrapper $out/libexec/Oni2_editor $out/bin/Oni2_editor
  '';
  meta = with lib; {
    description = "Native, lightweight modal code editor";
    license = licenses.unfree;
    homepage = "https://v2.onivim.io/";
  };
}