reverbs.scd

(
(1..SuperDirt.maxSampleNumChannels).do { |numChannels|

SynthDef("global_greyhole" ++ numChannels, {
	|dryBus, effectBus, gdelay = 2, gdamp = 0.5, gsize = 1, gdiff = 0.707,
	gfeedback = 0.9, gdepth = 0.1, gfreq = 2.0, gverb = 0.5
	|
	var sig = In.ar(dryBus, ~dirt.numChannels);
	var verbd = Greyhole.ar(sig,
		delayTime: gdelay,
		damp: gdamp,
		size: gsize,
		diff: gdiff,
		feedback: gfeedback,
		modDepth: gdepth,
		modFreq: gfreq
	);
	Out.ar(effectBus, verbd * gverb);
}, [\ir, \ir]).add;

SynthDef("global_jpverb" ++ numChannels, {
	|
	dryBus effectBus jpdelay=1 jpdamp=0.5 jpsize=1 jpdiff= 0.707 jpdepth=0.1
	jpfreq=2 jplow=1 jpmid=1 jphigh=1 jplowcut=500 jphighcut=2000 jpverb=0.5
	|
	var sig = In.ar(dryBus, ~dirt.numChannels);
	var verbd = JPverb.ar(sig,
		t60: jpdelay,
		damp: jpdamp,
		size: jpsize,
		earlyDiff: jpdiff,
		modDepth: jpdepth,
		modFreq: jpfreq,
		low: jplow,
		mid: jpmid,
		high: jphigh,
		lowcut: jplowcut
	);
	Out.ar(effectBus, verbd * jpverb);
}, [\ir, \ir]).add;


SynthDef("global_fverb" ++ numChannels, {
	var stereo = In.ar(\dryBus.ir, 2);
	var sig = FreeVerb2.ar(stereo[0], stereo[1], \fverb.ar(0.33), \fvroom.ar(0.5), \fvdamp.ar(0.5));
	ReplaceOut.ar(\out.ir, sig)
}).add;
};
);