Helper script to improve Windows 10 user experience.

uxp.cmd

@echo off
if "%1" == "elevated" goto start
powershell -command "Start-Process %~nx0 elevated -Verb runas"
goto :eof



:start
	@echo off
	cls
	
	echo.
	echo UXP Helper
	echo ==========
	echo.
	
	CALL :CHECK
	
	echo. 
	choice /M "Set preferred (P) or Quit (Q)" /C PQ
	
	if %ERRORLEVEL% == 1 ( CALL :PREFERRED )
	if %ERRORLEVEL% == 2 ( goto :eof )
	
	goto :start

:PREFERRED
	reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SubscribedContent-338387Enabled /t REG_DWORD /d 0 /f
	reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SubscribedContent-338388Enabled /t REG_DWORD /d 0 /f
	reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Search" /v SearchboxTaskbarMode /t REG_DWORD /d 1 /f
	reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v TaskbarGlomLevel /t REG_DWORD /d 2 /f
	reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Feeds" /v ShellFeedsTaskbarViewMode /t REG_DWORD /d 2 /f
	reg add "HKLM\SOFTWARE\Policies\Microsoft\Edge" /v EdgeShoppingAssistantEnabled /t REG_DWORD /d 0 /f
	echo.
	taskkill /F /IM explorer.exe
	start explorer
	goto :eof


:CHECK
	
	echo Show tips on lock screen (1 on, 0 off) [preffered: 0]
	reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SubscribedContent-338387Enabled
	echo.
			
	echo Show suggestions in start (1 on, 0 off) [preffered: 0]
	reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SubscribedContent-338388Enabled
	echo.
		
	echo Search in taskbar (0 off, 1 icon, 2 box) [preffered: 1]
	reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Search" /v SearchboxTaskbarMode
	echo.
	
	echo Combine in taskbar (0 allways, 1 sometimes, 2 never) [preffered: 2]
	reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v TaskbarGlomLevel
	echo.
	
	echo News and Interests (0 icon and text, 1 icon only, 2 hide) [preffered: 2]
	reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Feeds" /v ShellFeedsTaskbarViewMode
	echo.
	
	echo Edge Shopping Plugin (0 disabled, 1 enabled) [preffered: 0]
	reg query "HKLM\SOFTWARE\Policies\Microsoft\Edge" /v EdgeShoppingAssistantEnabled
	echo.
	goto :eof