Iterators in gleam (responding to https://lobste.rs/s/3boto7/first_impressions_gleam_lots_joys_some#c_rtqsgu)

iterators.gleam

// WARNING: I have never programmed in gleam before and this is probably 
// considered very unideomatic/cursed. You have been warned! :P

import gleam/io
import gleam/option.{type Option, None, Some}

type Iterator(a) {
  Iterator(next: fn () -> Option(#(a, Iterator(a))))
}

fn list_iterator(xs: List(a)) -> Iterator(a) {
  Iterator(fn() {
    case xs {
      [] -> None
      [x, ..xs] -> Some(#(x, list_iterator(xs)))
    }
  })
}

fn map(xs: Iterator(a), f: fn(a) -> b) -> Iterator(b) {
  Iterator(fn() {
    case xs.next() {
      None -> None
      Some(#(x, xs)) -> Some(#(f(x), map(xs, f)))
    }
  })
}

fn collect_list(xs: Iterator(a)) -> List(a) {
  case xs.next() {
    None -> []
    Some(#(x, xs)) -> [x, ..collect_list(xs)]
  }
}

pub fn main() {
  let xs =
    list_iterator([1, 2, 3])
    |> map(fn(x) { x * x })
    |> collect_list
    
  io.debug(xs) // [1, 4, 9]
}