Bad Apple

BadApple.wl

(* Set current directory for sanity *)
SetDirectory["E:\\Development\\BadApple\\"];

(* Load the video in *)
badAppleVideo = Import["BadApple.mp4"];

frameList = ColorConvert[VideoFrameList[badAppleVideo, All], "Grayscale"];

(* This is dependent on how many CPU cores and RAM you have. *)
LaunchKernels[16];

ParallelDo[
    Export[
        (* Filename corresponds to frame number *)
        ToString[StringForm["BadApple_f``.flac", i]],
        (* Transform frame into an audio file... *)
        Audio[
            (* ...by treating the image as a spectrogram  *)
            InverseSpectrogram[
                Part[frameList, i],
                Automatic,
                Automatic,
                BartlettHannWindow, (* Seemingly the best window to minimise artefacts *)
                MaxIterations -> 10000000
            ],
            "Real64",
            SampleRate -> 48000 (* Some weirdo might wanna listen to the thing *)
        ],
        AudioEncoding -> "Integer24"
    ],
    {i, Length[frameList]},
    Method -> "FinestGrained"
] // AbsoluteTiming